I am BATman - IPChanger

Dzisiaj mam dla was drugi skrypt pliku wykonywalnego dla Windows. Tym razem myślę, że jest to coś bardziej przydatnego dla zwykłego użytkownika, szczególnie gdy często zmienia sieci. Skrypt IPChanger służy do sprawdzenia i zmiany IP kart sieciowych.

Niby można zrobić to klikając po okienkach, ale niestety nie jest to takie wygodne i łatwe, szczególnie, gdy chcemy szybko zmienić sieci. I tak musimy wszystkie adresy wpisać ręcznie w odpowiednie okno, więc czemu nie w jednym oknie konsoli? Zawsze można też przywrócić DHCP, czyli ustawienia domyślne.

Aby uruchomić ten skrypt należy skopiować go do pliku tekstowego i zapisać jako "IPChanger.bat", po czym kliknąć prawym przyciskiem myszy i uruchomić go jako administrator. Ważne aby wcześniej zapisać sobie wszystkie adresy IP przypisane kartom sieciowym (można je wyświetlić używając pierwszej opcji z menu) Jeżeli chcecie go tylko potestować możecie uruchomić go bez uprawnień administratora. Wtedy wszystkie zmiany jakie wprowadzicie nie zostaną zapisane..

Jeżeli ktoś zna się na komendach batchowych może nawet sobie wpisać w pliku gotowe adresy i przełączać się między nimi z menu. To o wiele wygodniejsze niż klikanie między oknami.

Kliknij aby wyświetlić kod

:: (c) Jagmin 2018

:start
cls
@echo off
echo ^==================
echo ^| IPCHANGER MENU ^|
echo ^==================
echo 1. IPConfig /all
echo 2. Set Static IP
echo 3. Set DHCP
echo 4. Exit
echo.

:choice
choice /C 1234 /N /M "Choose option:"
if errorlevel 4 goto end
if errorlevel 3 goto C
if errorlevel 2 goto B
if errorlevel 1 goto A

:A
@echo off
ipconfig /all
pause
goto start

:B
@echo off
netsh int show int
echo.
echo Please enter Static IP Address Information
echo.
echo Interface Name:
set /p Interface=
echo.
echo Static IP Address:
set /p IPAddr=
echo.
echo Subnet Mask (eg. 255.255.255.0):
set /p SubMask=
echo.
echo Default Gateway:
set /p DGate=
echo.
echo Preferred DNS (eg. 8.8.8.8):
set /p DNS1=
echo.
echo Alternative DNS (eg. 8.8.4.4):
set /p DNS2=
echo.
echo "Setting Static IP Information"
netsh interface ip set address "%Interface%" static %IPAddr% %SubMask% %DGate%
netsh interface ip set dns "%Interface%" static %DNS1%
netsh interface ip add dns "%Interface%" %DNS2% index=2
pause
goto start

:C
@echo off
netsh int show int
echo.
echo Resetting IP Address, Subnet Mask and DNS For DHCP
echo Interface Name:
set /p Interface=
netsh interface ip set address "%Interface%" dhcp
netsh interface ip set dns "%Interface%" dhcp
ipconfig /renew
pause
goto start

:end